ATtiny85 タップテンポ付LFO その2

const int PWMpin = 1;
const int POTpin = 3;
const int SWpin = 4;

volatile byte rateCount = 0; // Timer0用カウンタ = 割り込み回数
volatile byte rateCountNum = 0; // Timer0 割り込み回数決定値
volatile int pwmCount = 0; // PWM用カウンタ 0～509
volatile unsigned long timeCount = 0; // タップ時間取得用カウンタ

unsigned long tapTime = 0; // タップ間隔時間
unsigned long timeTemp = 0; // タップ間隔時間一時保存用
unsigned long swCount = 0; // スイッチ用カウンタ
const byte rateAdj = 99; // 周期補正率 % 実測して設定
int oldPOTvalue = 2000; // 前回ADC読取値
int newPOTvalue = 2000; // 今回ADC読取値

void setup() {
  PLLCSR |= (1 << PLLE);  // Timer1 PLL許可
  delayMicroseconds(200); // Timer1 PLL許可後安定するまで待機
  PLLCSR |= (1 << PCKE);  // Timer1 PCK(64MHz)許可
  TCCR1 = 0b01100001;     // Timer1 PWM動作A 分周なし
  OCR1A = 100;            // Timer1 比較Aの値 = PWMデューティ比
  TCCR0A = 0b00000010;    // Timer0 CTCモード
  TCCR0B = 0b00000010;    // Timer0 クロック8分周
  TIMSK |= (1 << OCIE0A); // Timer0 比較A割り込み許可
  OCR0A = 100;            // Timer0 比較Aの値 = 割り込み間隔 us
  pinMode(PWMpin, OUTPUT);
  pinMode(POTpin, INPUT);
  pinMode(SWpin, INPUT_PULLUP);
  sei(); // 全割り込み許可
}

// LFO（Timer0 比較A割り込み）---------------------------------------
ISR(TIMER0_COMPA_vect) {
  if (rateCount == rateCountNum) {
    rateCount = 0;
    if (pwmCount == 510) pwmCount = 0;
    if (pwmCount < 256) OCR1A = pwmCount; // 三角波（上昇）
    else OCR1A = 510 - pwmCount;          // 三角波（下降）
    pwmCount++;
  }
  rateCount++;
  timeCount++;
}

void loop() { // 1ループ約0.14ms
  // タップテンポ ---------------------------------------------------
  if (digitalRead(SWpin) == LOW) {
    swCount++;
    if (swCount == 70) { // チャタリング対策 10msスイッチ押下で検出
      // 前回スイッチ検出から経過した時間を記録
      tapTime = timeTemp + timeCount * OCR0A * 0.001;
      timeTemp = 0; // 経過時間をリセット
      timeCount = 0;
      if ( 100 < tapTime && tapTime < 3000) { // 周期制限 0.1秒～3秒
        // デューティ比変更間隔時間へ換算（*1000/510*周期補正率）
        rateCalc(tapTime * 1.96078 * rateAdj * 0.01);
      }
    }
  }
  else swCount = 0;

  // ADC ------------------------------------------------------------
  newPOTvalue = analogRead(POTpin); // 読取値が4以上変化で変更
  if (abs(newPOTvalue - oldPOTvalue) > 3) {
    rateCalc((100 + 3 * newPOTvalue) * 1.96078 * rateAdj * 0.01);
    oldPOTvalue = newPOTvalue;
  }
}

// デューティ比変更間隔時間(x)変更計算 x = p * q + r ----------------
void rateCalc(int x) {
  byte q; // 商
  byte r; // 余り
  int pMin;
  byte qMin;
  byte rMin = 255;
  for (int p = 255; p > 99; p--) { // 除数255から100まで計算
    q = x / p;
    r = x % p;
    if (r < rMin) { // 余りrが最小値の時の値を記録
      pMin = p;
      qMin = q;
      rMin = r;
    }
  }
  // OCR0A変更前に経過した時間をtimeTempに代入した後、
  // カウンタをリセットして新しいOCR0Aで再度カウント開始
  timeTemp = timeTemp + timeCount * OCR0A * 0.001;
  timeCount = 0;
  OCR0A = pMin;
  rateCountNum = qMin;
  rateCount = 0;
}